# Common settings suitable on all machines
################################################

#### initial system paths 
 
set path=( . /usr/local/bin /usr/bin /bin )

setenv HOSTNAME `hostname -s`

setenv EDITOR nano	# this seems easier to use than vi

# directory containing user environment configurations

setenv USERHOME	/opt/nfsapps/morozov_apps/config_user

# directory containing program scripts and configurations

setenv PROGHOME	/opt/nfsapps/morozov_apps/config_prog	# was before: setenv PROGHOME /geofile/home/geoapps

# root directory for third-party applications

setenv GEOAPPS	/opt/nfsapps/geol_apps/geoepos/apps	# was before: setenv GEOAPPS /geoepos/apps
setenv GEOAPPS1	/opt/nfsapps/geol_apps/apps		# was before: setenv GEOAPPS /geofile/apps

# list files in color and in columns
alias ls 'ls --color -C'

# Remember last 100 commands
set history = 100

# Suppress core file dumps
limit coredumpsize 0

# For interactive shells, set the prompt to show the host name and event number:

if ( (! $?ENVONLY) && $?prompt ) then
	if ( -o /bin/su ) then
		set prompt="`/bin/hostname -s` \!# "
	else
		set prompt="`/bin/hostname -s` \!% "
	endif
endif

# System-specific settings for different machines and users
#############################################################

if ( `/bin/uname -p` == "x86_64" ) then
	setenv HOSTARCH "64bit"
else
	setenv HOSTARCH "32bit"
endif

setenv CONFIGNAME students		# default configuration for all student machines

if ( -d $USERHOME ) then		# master configuration directory exists

	#echo Synchronizing configuration with $USERHOME

	rsync -CHavzq $USERHOME/README ~/README			# update user's copy of this README file

	rsync -CHavzq $USERHOME/.cshrc.all ~/.cshrc.all		# update .cshrc.all in case it was changed
	rsync -CHavzq $USERHOME/.cshrc1.all ~/.cshrc1.all	

	if ( -r $USERHOME/.cshrc.$HOSTNAME.$USER ) then		# copy configuration script for $USER on this machine

		setenv CONFIGNAME $HOSTNAME.$USER

	else 

#		echo Checking $USERHOME/.cshrc.$USER

		if ( -r $USERHOME/.cshrc.$USER ) then		# copy configuration script for $USER on any machine

			setenv CONFIGNAME $USER

		else if ( -r $USERHOME/.cshrc.$HOSTNAME ) then		# copy configuration for anyone on this machine

			setenv CONFIGNAME $HOSTNAME
		endif

	endif	

		# update configuration from master

	rsync -CHavzq $USERHOME/.cshrc.$CONFIGNAME ~/.cshrc.$CONFIGNAME

else if ( -r ~/.cshrc.$HOSTNAME ) then		# no mount of $USERHOME but have local setup

	setenv CONFIGNAME $HOSTNAME
endif

#echo Executing custom config

echo User = $USER  Host = $HOSTNAME " ==> Using configuration " $HOME/.cshrc.$CONFIGNAME

source ~/.cshrc.$CONFIGNAME		# custom configuration for this user and machine
source ~/.cshrc1.all			# the remainder of common settings

unsetenv HOSTARCH
unsetenv HOSTNAME